plugins {
    alias(libs.plugins.pluginyml.bukkit)
    alias(libs.plugins.shadow)
    id("authmevelocity.spotless")
}

repositories {
    maven("https://repo.codemc.org/repository/maven-public/") {
        mavenContent {
            includeGroup("fr.xephi")
        }
    }
    maven("https://repo.alessiodp.com/releases/"){
        mavenContent {
            includeGroup("net.byteflux")
        }
    }
    maven("https://jitpack.io") {
        mavenContent {
            includeGroup("com.github.4drian3d")
        }
    }
}

dependencies {
    compileOnly(projects.authmevelocityCommon)
    compileOnly(projects.authmevelocityApiPaper)
    compileOnly(libs.paper)
    compileOnly(libs.authme)
    compileOnly(libs.miniplaceholders)
    shadow(libs.libby.bukkit)
}

bukkit {
    name = "AuthMeVelocity"
    main = "io.github._4drian3d.authmevelocity.paper.AuthMeVelocityPlugin"
    apiVersion = "1.13"
    website = project.property("url") as String
    description = project.description as String
    authors = listOf("xQuickGlare", "4drian3d")
    softDepend = listOf("MiniPlaceholders")
    depend = listOf("AuthMe")
    version = project.version as String
}

tasks {
    shadowJar {
        duplicatesStrategy = DuplicatesStrategy.EXCLUDE
        relocate("net.byteflux.libby", "io.github._4drian3d.authmevelocity.libs.libby")
        configurations = listOf(project.configurations.shadow.get())
    }
}